Mercurial > repos > blastem

comparison shaders/crt.f.glsl @ 1392:4942da159194

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Added a "subtle" CRT shader contributed by Anael Seghezzi
author Michael Pavone <pavone@retrodev.com>
date Sun, 04 Jun 2017 10:07:36 -0700
parents
children 7da675d0c512
comparison
equal deleted inserted replaced
1391:99d153d9e9ca 1392:4942da159194
1 #version 110
2
3 /* Subtle CRT shader usable in fullscreen - Anaël Seghezzi [anael(at)maratis3d.com]
4 This shader is free software distributed under the terms of the GNU General Public
5 License version 3 or higher. This gives you the right to redistribute and/or
6 modify the program as long as you follow the terms of the license. See the file
7 COPYING for full license details.
8 */
9
10 #define M_PI 3.14159265358979323846
11
12 uniform sampler2D textures[2];
13 uniform float width, height;
14 varying vec2 texcoord;
15 varying vec2 screencoord;
16
17
18 float nrand(vec2 n) {
19 return fract(sin(dot(n.xy, vec2(12.9898, 78.233))) * 43758.5453);
20 }
21
22 float scanline(vec2 texco)
23 {
24 return (1.0 - abs(cos(texco.y * 512.0 * M_PI)));
25 }
26
27 vec2 sharp_coord(vec2 texco, vec2 dim, vec2 sharpness)
28 {
29 vec2 texcoif = texco * dim;
30 vec2 texcoi = floor(texcoif);
31 vec2 mu = (texcoif - 0.5) - texcoi;
32 vec2 mub = pow(abs(mu) * 2.0, sharpness) * sign(mu) * 0.5;
33 return (texcoi + mub + 0.5) / dim;
34 }
35
36 void main()
37 {
38 float v = 1.0 / 512.0;
39 float yforce = 0.175;
40 float vign = length(screencoord);
41
42 // monitor deformation
43 vec2 monitorcoord = (screencoord + screencoord * vign * 0.025);
44
45 if (monitorcoord.x < -1.0 || monitorcoord.y < -1.0 || monitorcoord.x > 1.0 || monitorcoord.y > 1.0) {
46 gl_FragColor = vec4(0.0);
47 return;
48 }
49
50 vec2 texco = monitorcoord * vec2(width/1024.0, height/-1024.0) + vec2(width/1024.0, height/1024.0);
51
52 // mask
53 float maskx = 1.0 - pow(monitorcoord.x, 200.0);
54 float masky = 1.0 - pow(-monitorcoord.y, 200.0);
55 float mask = clamp(maskx * masky, 0.0, 1.0);
56
57 // sharp texcoord
58 vec2 texco_sharp0 = sharp_coord(texco, vec2(512.0, 512.0), vec2(4.0, 8.0));
59 vec2 texco_sharp1 = sharp_coord(texco - vec2(0.0, 1.0 / 1024.0), vec2(512.0, 512.0), vec2(4.0, 8.0));
60
61 vec4 src0 = texture2D(textures[0], texco_sharp0);
62 vec4 src1 = texture2D(textures[1], texco_sharp1);
63
64 // interlace mix
65 float interlace = cos((texco.y * 1024.0) * M_PI);
66 vec4 src_mix = mix(src0, src1, interlace * 0.5 + 0.5);
67
68 // blur
69 vec4 src_blur = mix(texture2D(textures[0], texco), texture2D(textures[1], texco), 0.5);
70
71 #ifdef NO_SCANLINE
72
73 gl_FragColor = (src_mix * 0.95 + (src_blur * (1.6 - vign * 0.4) * 0.1)) * mask;
74
75 #else
76 // multisample scanline with grain
77 // TODO: offset grain with time (needs a "frame" uniform)
78 float cosy;
79 cosy = scanline(texco + vec2(0.125, v * (nrand(texcoord + vec2(0.0, 1.0)) * 0.25) + 0.3333));
80 cosy += scanline(texco + vec2(0.25, v * (nrand(texcoord + vec2(0.0, 2.0)) * 0.25) + 0.25));
81 cosy += scanline(texco + vec2(0.50, v * (nrand(texcoord + vec2(0.0, 3.0)) * 0.25) + 0.6666));
82 cosy += scanline(texco + vec2(0.75, v * (nrand(texcoord + vec2(0.0, 4.0)) * 0.25) + 0.75));
83 cosy *= 0.25;
84
85 // final scanline + burn
86 gl_FragColor = ((src_mix * ((1.0 - yforce) + cosy * yforce)) + (src_blur * (1.6 - vign * 0.4) * 0.1)) * mask;
87
88 #endif
89 }